(* ************************** *)
(* *****  Information   ***** *)
(* ************************** *)
M$ModelName = "Scotogenic";

M$Information = {
  Authors      -> {"A. Vicente"}, 
  Version      -> "1.0",
  Date         -> "23. 06. 2022",
  Institutions -> {"IFIC"},
  Emails       -> {"avelino.vicente@ific.uv.es"}
};


(* ************************** *)
(* **** Particle classes **** *)
(* ************************** *)
M$ClassesDescription = {


  F[37] == {
    ClassName        -> Neu1,
    SelfConjugate    -> True,
    Mass             -> MN1,
    FullName         -> "heavy",
    Width            -> 0
  },

  F[38] == {
    ClassName        -> Neu2,
    SelfConjugate    -> True,
    Mass             -> MN2,
    FullName         -> "heavy",
    Width            -> 0
  },

  F[39] == {
    ClassName        -> Neu3,
    SelfConjugate    -> True,
    Mass             -> MN3,
    FullName         -> "heavy",
    Width            -> 0
  },

  S[105] == {
    ClassName      -> Eta,
    Indices        -> {Index[SU2D]},
    SelfConjugate  -> False,
    Mass             -> muEta,
    FullName        -> "heavy",
    QuantumNumbers -> {Y -> 1/2}
  }

};

(* ************************** *)
(* *****   Parameters   ***** *)
(* ************************** *)
M$Parameters = {

  (* External parameters *)

  (* Internal Parameters *)
  Ynu1 == { 
    ParameterType     -> Internal, 
    Indices           -> {Index[Generation]},
    ComplexParameter  -> True
  },

  Ynu2 == { 
    ParameterType     -> Internal, 
    Indices           -> {Index[Generation]},
    ComplexParameter  -> True
  },

  Ynu3 == { 
    ParameterType     -> Internal, 
    Indices           -> {Index[Generation]},
    ComplexParameter  -> True
  },

  MN1 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  MN2 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  MN3 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  muEta == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  lam2 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  lam3 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  lam4 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> False
  },

  lam5 == { 
    ParameterType     -> Internal, 
    ComplexParameter  -> True
  }

};



(* ************************** *)
(* *****   Lagrangian   ***** *)
(* ************************** *)

gotoBFM={G[a__]->G[a]+GQuantum[a],Wi[a__]->Wi[a]+WiQuantum[a],B[a__]->B[a]+BQuantum[a]};

LN := Block[{mu}, 
   I*(Neu1bar.Ga[mu].DC[Neu1, mu])-MN1*Neu1bar.Neu1/2
  +I*(Neu2bar.Ga[mu].DC[Neu2, mu])-MN2*Neu2bar.Neu2/2
  +I*(Neu3bar.Ga[mu].DC[Neu3, mu])-MN3*Neu3bar.Neu3/2
]/.gotoBFM;

LEta := Block[{ii,jj,mu},
  DC[Etabar[ii],mu] DC[Eta[ii],mu] - muEta^2 Etabar[ii] Eta[ii] - lam2 Etabar[ii] Eta[ii] Etabar[jj] Eta[jj]]/.gotoBFM;

LEtaPhi1 := Block[{ii,jj},
  - lam3 Phibar[ii] Phi[ii] Etabar[jj] Eta[jj] -lam4 Phibar[ii] Eta[ii] Etabar[jj] Phi[jj]];

LEtaPhi2 := Block[{ii,jj},
  lam5term = 
  - lam5/2 Phibar[ii] Eta[ii] Phibar[jj] Eta[jj];
  lam5term+HC[lam5term]
  ];

LYuk := Block[{sp1,ii,jj,ff1,yuk}, 
  yuk =
   -Ynu1[ff1] Neu1bar[sp1].LL[sp1,ii,ff1] Eta[jj] Eps[ii,jj]
   -Ynu2[ff1] Neu2bar[sp1].LL[sp1,ii,ff1] Eta[jj] Eps[ii,jj]
   -Ynu3[ff1] Neu3bar[sp1].LL[sp1,ii,ff1] Eta[jj] Eps[ii,jj];
  yuk+HC[yuk]
 ];

LNP := LN + LEta + LEtaPhi1 + LEtaPhi2 + LYuk;

Ltot := LSM + LNP;