#############First plot (KN cross section except for constants)

reset
set terminal postscript eps enhanced color font 'Helvetica,20' lw 1.6
set output 'kn.eps'
unset border
set polar
set angles degrees #set gnuplot on degrees instead of radians https://stackoverflow.com/questions/6772135/how-to-get-a-radialpolar-plot-using-gnu-plot

set style line 10 lt 1 lc 0 lw 0.3 #redefine a new line style for the grid
set grid polar 30 #set the grid to be displayed every x degrees

rango=2
rango2=rango+0.2
set xrange [-rango:rango]
set yrange [-rango:rango]

set xtics axis #disply the xtics on the axis instead of on the border
set ytics axis

set xtics scale 0 #"remove" the tics so that only the y tics are displayed
set xtics ("" 1, "" 2) #set the xtics only go from 0 to 6000 with increment of1000 but do not display anything. This has to be done otherwise the grid will not be displayed correctly.
set ytics 0, 1, rango

set_label(x, text) = sprintf("set label '%s' at (rango2*cos(%f)), (rango2*sin(%f))     center", text, x, x) #this places a label on the outside

#here all labels are created
eval set_label(0, "0")
eval set_label(60, "{/Symbol p}/3")
eval set_label(120, "2{/Symbol p}/3")
eval set_label(180, "{/Symbol p}")
eval set_label(240, "4{/Symbol p}/3")
eval set_label(300, "5{/Symbol p}/3")

set key rmargin
set key spacing 1.5
set size ratio -1

set style line 11 lt 1 lw 2 pt 2 ps 2 #set the line style for the plot

#and finally the plot
P(t,E)=1.0/(1.0+E/511.0*(1-cos(t)))
s(t,E)=P(t,E)**3+P(t,E)-P(t,E)**2*sin(t)*sin(t)
plot s(t,511) lt 1 lw 2 lc 1 ti "{/Helvetica-Italic E}_{/Symbol g}=511{/Helvetica-Italic keV}", s(t,200) lt 1 lw 2 lc 2 ti "{/Helvetica-Italic E}_{/Symbol g}=200{/Helvetica-Italic keV}", s(t,75) lt 1 lw 2 lc 3 ti "{/Helvetica-Italic E}_{/Symbol g}=75{/Helvetica-Italic keV}", s(t,25) lt 1 lw 2 lc 4 ti "{/Helvetica-Italic E}_{/Symbol g}=25{/Helvetica-Italic keV}"#, s(t,1) lt 1 lw 2 lc 5 ti "{/Helvetica-Italic E}_{/Symbol g}=1{/Helvetica-Italic keV}"


#############Second plot (KN normalized pdf)


reset
set terminal postscript eps enhanced color font 'Helvetica,20' lw 1.6
set output 'kn2.eps'
set key spacing 1.5
set ylabel '{/Helvetica-Italic f}{/Symbol _g(q)}'
set xlabel '{/Helvetica-Italic Scatter angle }{/Symbol q}'
set xrange [0:pi]
set xtics (0, '{/Symbol p/4}' pi/4, '{/Symbol p/2}' pi/2, '{/Symbol 3p/4}' 3*pi/4, '{/Symbol p}' pi)
g(E)=E/511.0
P(x,E)=1.0/(1.0+g(E)*(1-cos(x)))
st(E)=1.0/g(E)**3*(2.0*g(E)*(2.0+g(E)*(1.0+g(E))*(8.0+g(E)))/(1.0+2.0*g(E))**2+(g(E)*(g(E)-2.)-2.)*log(1.+2.*g(E)))
s(x,E)=(P(x,E)**3+P(x,E)-P(x,E)**2*sin(x)*sin(x))*sin(x)/st(E)
plot s(x,511) lt 1 lw 2 lc 1 ti "{/Helvetica-Italic E}_{/Symbol g}=511{/Helvetica-Italic keV}", s(x,200) lt 1 lw 2 lc 2 ti "{/Helvetica-Italic E}_{/Symbol g}=200{/Helvetica-Italic keV}", s(x,75) lt 1 lw 2 lc 3 ti "{/Helvetica-Italic E}_{/Symbol g}=75{/Helvetica-Italic keV}", s(x,25) lt 1 lw 2 lc 4 ti "{/Helvetica-Italic E}_{/Symbol g}=25{/Helvetica-Italic keV}"#, s(x,1) lt 1 lw 2 lc 5 ti "{/Helvetica-Italic E}_{/Symbol g}=1{/Helvetica-Italic keV}"
q